Export Struct-like objects for arrays

Question

I have been bashing my head about this and can't seem to figure it out. In another engine, I could make a struct, then make an array of that struct that I could then edit in the inspector. There seems to be no way of doing this that I can find in Godot.

I want to have a Resource that holds the starting Value and Type of multiple faces on a dice. For example, one side could have "2 Damage" while another has "Heal 3." (this is a first-time godot experiment inspired by Slice&Dice). Every tutorial I watch however makes it seem like, if I want to do so, I'd have to make a completely new Resource for each combination of Value and Type (Damage 1 Resource, Damage 2 Resource, etc.)

class_name DiceResource extends Resource

class DiceFaceData:
    export var BaseValue = 0
    export(Resource) var Type = preload("Resources/DiceFaceTypes/Damage.tres")
    func _init():
        Type = 2
        BaseValue = preload("Resources/DiceFaceTypes/Damage.tres")

export(Array) var Faces = [DiceFaceData.new()]

I cannot get DiceFaceData to show up in the Inspector's array, or be on the list of object types for an array. Extending Object doesn't work. Extending Node means I have to instantiate it, which I don't want to do for an editor-only Resource.

I find it hard to imagine Godot doesn't have anything like this available. Is there anything I can load in the inspector as just data and not have to instantiate it? Another option is create two arrays, one with int and another Resource, but that seems inconvenient to fill out. Or should I just give up with Resources and make everything a Node attached to a Node attached to a Node? Thanks!

Godot version 3.4.3

EDIT: If you're someone coming from Unity or Unreal, what you're looking for is Resource. While compared to ScriptableObjects or DataAssets from those other engines, that's not the complete answer. You would think, because of the way those game engines handle it, you can only create custom SO or DA as assets in the filesystem/content browser, but you can also use Resources as instanced classes. Instead of creating a new Resource in the filesystem, you can use

export(Resource) var n = preload("res://MyResourceScript.gd").new()

In the inspector, you can choose from the list New MyResourceScript and create it. You won't be referencing an externally made Reference file, you'll be creating a custom one right there. And look at the below answer as well on good tips for using Resources in cool ways.

Answer 1

First of all, I want to say that I sympathize. Custom resources and the inspector do not work well. There is a solution on the work… However that does not mean that the only thing we can do is keep Waiting For Godot.

---

Observations on your code

About your code, I want to point out that DiceFaceData is not a resource type. You could write it like this:

class DiceFaceData extends Resource:
    export var BaseValue = 0
    export(Resource) var Type = preload("Resources/DiceFaceTypes/Damage.tres")
    func _init():
        Type = 2
        BaseValue = preload("Resources/DiceFaceTypes/Damage.tres")

And… That solves nothing.

And, also, by the way, I remind you can put it on its own file:

class_name DiceFaceData
extends Resource:

export var BaseValue = 0
export(Resource) var Type = preload("Resources/DiceFaceTypes/Damage.tres")
func _init():
    Type = 2
    BaseValue = preload("Resources/DiceFaceTypes/Damage.tres")

And… That is not the solution either.

---

Something else I want to point out is that GDScript has types. See Static typing in GDScript. Use them. To illustrate…

This is a Variant with an ìnt value

var BaseValue = 0

This is an int, typed explicitly:

var BaseValue:int = 0

And this is an int, typed implicitly with type inference:

var BaseValue := 0

And if you were using types Godot would tell you that this is an error:

BaseValue = preload("Resources/DiceFaceTypes/Damage.tres")

Because BaseValue is an int, and you setting a resource to it.

---

The Array of Resources problem

First of all, this is a Variant that happens to have an Array value, and it is exported as an Array:

export(Array) var Faces = []

Let us type it as an Array:

export(Array) var Faces := []

And sadly we cannot specify the type of the elements of the arrays in Godot 3.x (we need Godot 4.0 for that feature). However we can specify how we export it.

So, this is an Array exported as an Array of Resource:

export(Array, Resource) var Faces := []

See Exporting arrays.

Before you could not get your custom resource type to show up. And now you have the opposite problem: all the resource types show up. And this includes your custom resource type, if it in its own file.

You would guess that we need to specify the resource type we want:

export(Array, DiceFaceData) var Faces = []

And that would be correct if it were a build-in resource type. But it is a custom one. We are expecting this to be fixed in a future version. Meanwhile we will have to leave it with export(Array, Resource).

---

Mitigating the problem with an addon

To alleviate the pain of having all the possible resource types, consider using the addon "Improved resource picker" by MakovWait. You can find it on itch, or on github.

---

A proper solution

Anyway, we can do better. But you are going to need to make your script a tool script (you do that by putting tool on the top of the script, and it means that the code from the script can and will run on the editor).

We are going to define a setter with setget, and in there we are going to make sure the elements are of the correct type:

export(Array, Resource) var Faces = [] setget set_faces

func set_faces(new_value:Array) -> void:
    Faces = []
    for element in new_value:
        element = element as DiceFaceData
        if element == null:
            element = DiceFaceData.new()

        Faces.append(element)

Now, in the inspector panel when you increase the size of the array, Godot will insert a new null element to the array, which makes the setter we defined run, which will find that null and convert it to a new instance of your custom resource type, so you don't have to pick the resource type in the inspector panel at all.

---

A "hacky" solution

As you know, this does not work:

export(Array, DiceFaceData) var Faces = []

However, we can replace an export with _get_property_list. What happens is that Godot asks the object what properties it has to show up in the inspector panel. Godot does this by calling get_property_list And it will statically report the ones it found while parsing (the ones with export). However, Godot also defines a function _get_property_list where we can add more at run time.

See also Advanced exports.

Which begs the question, could we possibly make it work with _get_property_list? Kind of. The The code like this:

var Faces := []

func _get_property_list() -> Array:
    return [
        {
            name = "Faces",
            type = TYPE_ARRAY,
            hint = 24,
            hint_string = "17/17:DiceFaceData"
        }
    ]

It will show up on the inspector as an array where the elements can only be of your custom resource type.

The issue is that it causes some error spam. Which you might or might not be OK with. It is your project, so it is up to you.

I know it looks like voodoo magic in part because we are using some undocumented stuff. If you want an explanation of that 24 and that 17/17: see How to add Array with hint and hint_string?.

---

About the sub-resources

Every tutorial I watch however makes it seem like, if I want to do so, I'd have to make a completely new Resource for each combination of Value and Type (Damage 1 Resource, Damage 2 Resource, etc.)

I'm not sure what you are getting to with "a completely new Resource", but yes. A resource is an instance of a resource type. And each of those combination would be a resource.

Perhaps "Damage", "Heal" and so on are resources too. Let us see… I'm guessing that is what the Type is for:

export(Resource) var Type = preload("Resources/DiceFaceTypes/Damage.tres")

Godot would be showing all the resource types it is aware of, which is a pain. I'm going to suggest a different approach than those above for this: Make an String enumeration.

export(String, "Damage", "Heal") var Type:String

That will show up as a drop down list on the inspector panel, with the options you specified.

Why String and not int? Ah, because you can then do this if you so desire:

var type_resource := load("Resources/DiceFaceTypes/" + Type + ".tres")

I'm assuming that those have the code that actually does damage or heal or whatever.

---

Alright, but when you add a new type of dice face, you would have to come here and update it… Or do you? With the power of tool scripts we are going to update that list to reflect the files that actually exist!

First of all, we are not going to use export, so it will be just:

var Type:String

And now we can export it from _get_property_list. There we can query the files. But before we do that, so we are clear what we have to do, the following code is equivalent to the export we had before:

func _get_property_list() -> Array:
    return [
        {
            name = "Type",
            type = TYPE_STRING,
            hint = PROPERTY_HINT_ENUM,
            hint_string = "Damage,Heal"
        }
    ]

No undocumented stuff here.

Our task is to build that hint_string with the names of the files. And that looks like this:

const path := "res://"

func _get_property_list() -> Array:
    var hint_string := ""
    var directory := Directory.new()
    if OK != directory.open(path) or OK != directory.list_dir_begin(true):
        push_error("Unable to read path: " + path)
        return []

    var file_name := directory.get_next()
    while file_name != "":
        if not directory.current_is_dir() and file_name.get_extension() == "tres":
            if hint_string != "":
                hint_string += ","

            hint_string += file_name

        file_name = directory.get_next()

    directory.list_dir_end()
    return [
        {
            name = "Type",
            type = TYPE_STRING,
            hint = PROPERTY_HINT_ENUM,
            hint_string = hint_string
        }
    ]

Ah, yes, set the path constant to the path of the folder where the resources types you have are.

---

Addendum post edit

I want to elaborate on this example:

export(Resource) var n = preload("res://MyResourceScript.gd").new()

Here we are exporting a variable n as a Resource, which will appear in the Inspector panel. The variable is currently a Variant, we could type it Resource:

export(Resource) var n:Resource = preload("res://MyResourceScript.gd").new()

And then we don't need to tell Godot to export it as a Resource, because it is a Resource:

export var n:Resource = preload("res://MyResourceScript.gd").new()

---

Something else we can do is preload into a const. To be clear, preloads are resolved at parse time. Like this:

const MyResourceScript := preload("res://MyResourceScript.gd")

export var n:Resource = MyResourceScript.new()

This way, if you need to use the same script in multiple places, you don't need to repeat the path.

---

However, you might not need the path at all. If in the script res://MyResourceScript.gd we add a class_name (at the top of the script):

class_name MyResourceScript

Then we don't need to use preload at all. That name will be available everywhere, and you can just use it:

export var n:Resource = MyResourceScript.new()

---

Where is that resource stored?

Potentially nowhere. Above we are telling Godot to create a new one when our it initializes our object (e.g. which could be a Node, or another Resource - because, yes, Resources can have Resources) and those would only exist in RAM.

However, if you modify the Resource from the Inspector panel, Godot needs to store those changes somewhere. Now, if you are editing a Node, by default they go to the scene file. If you are editing another Resource, then it goes to wherever that Resource is stored. To be clear, scenes are resources too (PackedScene). And, yes, that means a file can have multiple Resources (A main resurce and sub-resources). You could also tell Godot to store the Resource in its own file from the Inspector panel. The advantage of giving a file to a Resource is in reusing it in multiple places (multiple scenes, for example).

So, a Resource could be stored in a file, or not stored at all. And a resource file could have a Resource alone, or it could also have sub-resources as well.

---

I'll take a moment to remind you that scenes can have instances of other scenes inside. So, there is no line between scenes and the so called "prefabs" in Godot.

---

… Did you know?

You can save the resources you created in runtime, using ResourceSaver. Which could be a way to save player progress, for example. You can also load them using load or ResourceLoader (in fact, load is a shorthand for ResourceLoader.load).

In fact, if you can use load or preload on something, it is a Resource. Wait a minute, we did this above:

const MyResourceScript := preload("res://MyResourceScript.gd")

Yep. The Script is a Resource. And yes, you can create that kind of resources in runtime too. Create a GDScript object (GDScript.new()), set its source_code, and reload it. Then you can attach it to an Object (e.g. a Node) with set_script. You can now start thinking of meta-programming, or modding support.