neo4j creating random empty nodes when merging

Question

I'm trying to create a new node with label C and relationships from a-->c and b-->c, but if and only if the whole pattern a-->c,b-->c does exist. a and b already exist (merged before the rest of the query).

The below query is a portion of the query I want to write to accomplish this.

However, it creates a random empty node devoid of properties and labels and attaches the relationship to that node instead. This shouldn't be possible and is certainty not what I want. How do I stop that from happening?

merge (a: A {id: 1})
merge (b: B {id:1})

with *
call {with a, b
     match (a)-[:is_required]->(dummy:C), (a)-[:is_required]->(b)
     with count(*) as cnt
     where cnt = 0
     merge (temp: Temporary {id: 12948125})
     merge (a)-[:is_required]->(temp)
     return temp
}
return *

Thanks

Answer 1

I think there are a couple of problems here:

1. There are restrictions on how you can use variables introduced with WITH in a sub-query. This article helps to explain them https://neo4j.com/developer/kb/conditional-cypher-execution/

2. I think you may be expecting the WHERE to introduce conditional flow like IF does in other languages. WHERE is a filter (maybe FILTER would have been a better choice of keyword than WHERE). In this case you are filtering out 'cnt's where they are 0, but then never reference cnt again, so the merge (temp: Temporary {id: 12948125}) and merge (a)-[:is_required]->(temp) always get executed. The trouble is, due to the above restrictions on using variables inside sub-queries, the (a) node you are trying to reference doesn't exist, it's not the one in the outer query. Neo4j then just creates an empty node, with no properties or labels and links it to the :Temporary node - this is completely valid and why you are getting empty nodes.

This query should result in what you intend:

merge (a: A {id: 1})
merge (b: B {id:1})

with *
// Check if a is connected to b or :C (can't use a again otherwise we'd overwrite it)
optional match(x:A {id: 1}) where exists((a)-[:is_required]->(:C)) or exists((a)-[:is_required]->(b))

with *, count(x) as cnt

// use a case to 'fool' foreach into creating the extra :Temporary node required if a is not related to b or :C
foreach ( i in case when cnt = 0 then [1] else [] end |
    merge (temp: Temporary {id: 12948125})
    merge (a)-[:is_required]->(temp)
)

with *
// Fetch the :Temporary node if it was created
optional match (a)-[:is_required]->(t:Temporary)

return *

There are apoc procedures you could use to perform conditional query execution (they are mentioned in the linked article). You could also play around with looking for a path from (a) and check its length, rather than introduce a new MATCH and the variable x then checking for the existance of related nodes.

Answer 2

If anyone is having the same problem, the answer is that the Neo4j browser is display nonexistent nodes. The query executes fine…