How do I get the DTE for running Visual Studio instance?

Question

How do I get all the running instances of Visual Studio so that I can do automation?

(added this question because this one was closed)

Answer 1

This below is the solution for VB.Net to get the CURRENT Visual Studio instance.

What I do is a simple string comparison with the processes that are debugging with the current assembly name. It seems to work as expected when multiple instances of VS are open, I tried it in debug and release mode, in Visual Studio 2013.

Imports:

Imports System
Imports System.Diagnostics.CodeAnalysis
Imports System.Runtime.InteropServices
Imports System.Runtime.InteropServices.ComTypes
Imports EnvDTE80

P/Invokes:

(NativeMethods.dll)

''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Returns a pointer to an implementation of <see cref="IBindCtx"/> (a bind context object).
''' <para></para>
''' This object stores information about a particular moniker-binding operation.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <remarks>
''' <see href="http://msdn.microsoft.com/en-us/library/windows/desktop/ms678542%28v=vs.85%29.aspx"/>
''' </remarks>
''' ----------------------------------------------------------------------------------------------------
''' <param name="reserved">
''' This parameter is reserved and must be 0.
''' </param>
''' 
''' <param name="ppbc">
''' Address of an <see cref="IBindCtx"/> pointer variable that receives the 
''' interface pointer to the new bind context object.
''' <para></para>
''' When the function is successful, the caller is responsible for calling Release on the bind context.
''' <para></para>
''' A value of <see langword="Nothing"/> for the <paramref name="ppbc"/> value indicates that an error occurred.
''' </param>
''' ----------------------------------------------------------------------------------------------------
''' <returns>
''' This function can return the standard return values <c>E_OUTOFMEMORY</c> and <c>S_OK</c>.
''' </returns>
''' ----------------------------------------------------------------------------------------------------
<SuppressMessage("Microsoft.Interoperability", "CA1401:PInvokesShouldNotBeVisible", justification:="Assembly Reference")>
<DllImport("ole32.dll")>
Public Shared Function CreateBindCtx(ByVal reserved As Integer,
                                     ByRef ppbc As IBindCtx
) As Integer
End Function

''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Returns a pointer to the <see cref="IRunningObjectTable"/> interface on the local running object table (ROT).
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <remarks>
''' <see href="http://msdn.microsoft.com/en-us/library/windows/desktop/ms684004%28v=vs.85%29.aspx"/>
''' </remarks>
''' ----------------------------------------------------------------------------------------------------
''' <param name="reserved">
''' This parameter is reserved and must be 0.
''' </param>
''' 
''' <param name="pprot">
''' The address of an <see cref="IRunningObjectTable"/> pointer variable that receives the 
''' interface pointer to the local ROT.
''' <para></para>
''' When the function is successful, the caller is responsible for calling Release on the interface pointer.
''' <para></para>
''' A value of <see langword="Nothing"/> for the <paramref name="pprot"/> value indicates that an error occurred.
''' </param>
''' ----------------------------------------------------------------------------------------------------
''' <returns>
''' This function can return the standard return values <c>E_UNEXPECTED</c> and <c>S_OK</c>.
''' </returns>
''' ----------------------------------------------------------------------------------------------------
<SuppressMessage("Microsoft.Interoperability", "CA1401:PInvokesShouldNotBeVisible", justification:="Assembly Reference")>
<DllImport("ole32.dll")>
Public Shared Function GetRunningObjectTable(ByVal reserved As Integer,
                                             ByRef pprot As IRunningObjectTable
) As Integer
End Function

Rest of code:

''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Gets a collection of the Visual Studio instances that are running on this PC.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <returns>
''' An <see cref="IEnumerable(Of DTE2)"/> that contains the running Visual Studio instances, if any.
''' </returns>
''' ----------------------------------------------------------------------------------------------------
Public Shared Iterator Function GetVisualStudioInstances() As IEnumerable(Of DTE2)

    Dim rot As IRunningObjectTable = Nothing
    Dim enumMoniker As IEnumMoniker = Nothing
    Dim retVal As Integer = NativeMethods.GetRunningObjectTable(0, rot)

    If (retVal = 0) Then

        rot.EnumRunning(enumMoniker)

        Dim fetched As IntPtr = IntPtr.Zero
        Dim moniker As IMoniker() = New IMoniker(0) {}

        While (enumMoniker.Next(1, moniker, fetched) = 0)

            Dim bindCtx As IBindCtx = Nothing
            NativeMethods.CreateBindCtx(0, bindCtx)

            Dim displayName As String = ""
            moniker(0).GetDisplayName(bindCtx, Nothing, displayName)

            If (displayName.StartsWith("!VisualStudio")) Then
                Dim obj As New Object
                rot.GetObject(moniker(0), obj)
                Yield DirectCast(obj, DTE2)
            End If

        End While

    End If

End Function

''' ----------------------------------------------------------------------------------------------------
''' <summary>
''' Gets a <see cref="DTE2"/> object that represents the current Visual Studio instance that is running this project.
''' </summary>
''' ----------------------------------------------------------------------------------------------------
''' <returns>
''' A <see cref="DTE2"/> object that represents the current Visual Studio instance that is running this project.
''' </returns>
''' ----------------------------------------------------------------------------------------------------
Public Shared Function GetCurrentVisualStudioInstance() As DTE2

    Dim currentInstance As DTE2 = Nothing
    Dim processName As String = Process.GetCurrentProcess.MainModule.FileName
    Dim instances As IEnumerable(Of DTE2) = GetVisualStudioInstances

    For Each instance As DTE2 In instances

        For Each p As EnvDTE.Process In instance.Debugger.DebuggedProcesses

            If (p.Name = processName) Then
                currentInstance = instance
                Exit For
            End If

        Next p

    Next instance

    Return currentInstance

End Function