sum function in Julia is giving error if the array is empty

Question

I am trying to create a code which identifies if the elements in an array are monotonic or not.

I wrote the below code and got the error -

function isMonotonic(array)
    if length(array) <= 2
        return true
    end
    check_up = []
    check_down = []
    for i in range(2, length(array))
        if array[i] <= array[i-1]
            append!(check_up, 1)
        end
        if array[i] >= array[i - 1]
            append!(check_down, 1)
        end
    end
    if sum(check_up) == length(array) - 1 || sum(check_down) == length(array) - 1
        return true
    else
        return false
    end
end
isMonotonic([1, 2, 3, 4, 5, 6 , 7])

I am getting the below error

Error: Methoderror: no method matching zero(::Type{Any})

I think it is because I am trying to sum up the empth array, I want to understand how to overcome this problem in general, I have a solution for the above code, but in genral I want to know the reason and how to use it. I do not want to first check if the array is empty or not and then do the sum.

Answer 1

If you wanted to save yourself lots of effort, the simplest solution would just be:

my_ismonotonic(x) = issorted(x) || issorted(x ; rev=true)

This will return true if x is sorted either forwards, or in reverse, and false otherwise.

We could maybe make it a little more efficient using a check so we only need a single call to issorted.

function my_ismonotonic(x)
    length(x) <= 2 && return true
    for n = 2:length(x)
        if x[n] > x[1]
            return issorted(x)
        elseif x[n] < x[1]
            return issorted(x ; rev=true)
        end
    end
    return true
end
# Alternatively, a neater version using findfirst
function my_ismonotonic(x)
    length(x) <= 2 && return true
    ii = findfirst(a -> a != x[1], x)
    isnothing(ii) && return true # All elements in x are equal
    if x[ii] > x[1]
        return issorted(x)
    else
        return issorted(x ; rev=true)
    end
end

The loop detects the first occurrence of an element greater than or less than the first element and then calls the appropriate issorted as soon as this occurs. If all elements in the array are equal then the loop runs over the whole array and returns true.

There are a few problems of efficiency in your approach, but the reason you are getting an actual error message is because given the input, either this expression sum(check_up) or this expression sum(check_down) will effectively result in the following call:

sum(Any[])

There is no obvious return value for this since the array could have any type, so instead you get an error. If you had used the following earlier in your function:

   check_up = Int[]
   check_down = Int[]

then you shouldn't have the same problem, because:

julia> sum(Int[])
0

Note also that append! is usually for appending a vector to a vector. If you just want to add a single element to a vector use push!.