Racket/Beginner Student Language Confusion

Question

I am trying to animate the word "floccinaucinihilipilification" letter by letter. Right now it displays the complete word in the animation window, but I am lost on how to animate it so it will count up from the first character to the last, looping back to 0.

(define LONG-WORD "floccinaucinihilipilification")

; cycle-spelling : String -> Image
; display an animation of a long
; word being spelled out

(define a (string-length LONG-WORD))
(define TXT
  (text (substring LONG-WORD 0 a) 30 "black"))
(define BG
  (empty-scene 400 400))
(define (cycle-spelling a)
  (place-image TXT 200 200 BG))

(animate cycle-spelling)

Answer 1

See what animate does:

(animate create-image) ? natural-number/c

create-image : (-> natural-number/c scene?)

opens a canvas and starts a clock that ticks 28 times per second. Every time the clock ticks, DrRacket applies create-image to the number of ticks passed since this function call. The results of these function calls are displayed in the canvas. The simulation runs until you click the Stop button in DrRacket or close the window. At that point, animate returns the number of ticks that have passed.

So you have to base your code on the number of ticks, passed to create-image function.

(animate cycle-spelling)

(define (cycle-spelling ticks) ... )

Start with (quotient ticks 28), value of this expression increases each second by 1.

Looping is created with modulo, so after some experimenting, you should have something like this:

(modulo (quotient ticks 28) (+ (string-length long-word) 1))

Rest of the code will be similar.

Following code animates given word letter by letter and then loops back to 0.

#lang racket

(require 2htdp/universe)
(require 2htdp/image)

(define long-word "floccinaucinihilipilification")

(define speed 3) ; try also 7, 14, 28 ...

(define bg
  (empty-scene 400 400))

(define (cycle-spelling ticks)
  (place-image (text (substring long-word 0
                                (modulo (quotient ticks speed)
                                        (+ (string-length long-word) 1)))
                     30 "black")
               200 200 bg))

(animate cycle-spelling)