Need to optimize the code for mapping codes to description

Question

I have a Text field that has semicolon separated codes. These code has to be replaced with the description. I have separate map that have code and description. There is a trigger that replace the code with their description. the data will loaded using the dataloader in this field. I am afraid, it might not work for large amount of data since I had to use inner for loops. Is there any way I can achieve this without inner for loops?

public static void updateStatus(Map<Id,Account> oldMap,Map < Id, Account > newMap)
    {
        Map<String,String> DataMap = new Map<String,String>();
        List<Data_Mapper__mdt> DataMapList = [select Salseforce_Value__c,External_Value__c from Data_Mapper__mdt where 
            active__c = true AND Field_API_Name__c= :CUSTOMFIELD_MASSTATUS AND 
            Object_API_Name__c= :OBJECT_ACCOUNT];
        
        for(Data_Mapper__mdt dataMapRec: DataMapList){
            DataMap.put(dataMapRec.External_Value__c,dataMapRec.Salseforce_Value__c);
        }
        for(Account objAcc : newMap.values())
        {
            if(objAcc.Status__c != ''){
                String updatedDescription='';
                List<String> delimitedList = objAcc.Status__c.split('; ');
                for(String Code: delimitedList) {
                    updatedDescription = DataMap.get(Code);
                }
                objAcc.Status__c = updatedDescription; 
            }

Answer 1

It should be fine. You have a map-based access acting like a dictionary, you have a query outside of the loop. Write an unit test that populates close to 200 accounts (that's how the trigger will be called in every data loader iteration). There could be some concerns if you'd have thousands of values in that Status__c but there's not much that can be done to optimise it.

But I want to ask you 3 things.

1. The way you wrote it the updatedDescription will always contain the last decoded value. Are you sure you didn't want to write something like updatedDescription += DataMap.get(Code) + ';'; or maybe add them to a List<String> and then call String.join on it. It looks bit weird. If you truly want first or last element - I'd add break; or really just access the last element of the split (and then you're right, you're removing the inner loop). But written like that this looks... weird.

2. Have you thought about multiple runs. I mean if there's a workflow rule/flow/process builder - you might enter this code again. And because you're overwriting the field I think it'll completely screw you over.

Map<String, String> mapping = new Map<String, String>{
    'one' => '1',
    'two' => '2',
    'three' => '3',
    '2' => 'lol'
};
String text = 'one;two';

List<String> temp = new List<String>();
for(String key : text.split(';')){
    temp.add(mapping.get(key));
}
text = String.join(temp, ';');
System.debug(text); // "1;2"

// Oh noo, a workflow caused my code to run again.
// Or user edited the account.

temp = new List<String>();
for(String key : text.split(';')){
    temp.add(mapping.get(key));
}
text = String.join(temp, ';');
System.debug(text); // "lol", some data was lost

// And again
temp = new List<String>();
for(String key : text.split(';')){
    temp.add(mapping.get(key));
}
text = String.join(temp, ';');
System.debug(text); // "", empty

3. Are you even sure you need this code. Salesforce is perfectly fine with having separate picklist labels (what's visible to the user) and api values (what's saved to database, referenced in Apex, validation rules...). Maybe you don't need this transformation at all. Maybe your company should look into Translation Workbench. Or even ditch this code completely and do some search-replace before invoking data loader, in some real ETL tool (or even MS Excel)