Converting char starting with "0b" or "0B" to unsigned long

Question

I am working on a project for a client so I am given a lot of code I cannot modify. I am stuff in a weird situation because of this problem. Nonetheless, I have a char with 34 indexes that I need to convert into an unsigned long type. I have seen numerous methods to accomplish this such as strtout, atol, etc. None have worked because the string starts with "0b" (ie "0b10000010000010000010000010000000"). Without the "0b", the rest of the code will not function properly. I tested with varying beginning 2 chars but nothing has led to a successful trial. Is there a function or code available that can convert the previously mentioned string into unsigned long? Any help is greatly appreciated.

Answer 1

You can combine the fact that a character - '0' is the number of that digit and use bit shifting to build the number up from the string:

unsigned long binaryToUL(String numberString){
  int i;
  unsigned long answer = 0;

  if(numberString.startsWith("0b"))
    for(i = 2; i<numberString.length(); i++)
      answer = (answer << 1) + (numberString[i] - '0');

  return answer;
}

void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);
}

void loop() {
  // put your main code here, to run repeatedly:
  unsigned long test;
  String testString = "0b10000010000010000010000010000000";

  test = binaryToUL(testString);
  Serial.println(testString);
  Serial.println(test,BIN);
  Serial.println(test);

  while(true)
    ;
}

Answer 2

To convert a string a string representation of a binary that started with a "0b" or "0B", you need to remove the header first, then convert to the an unsigned long (uint32_t). Depend on what is the original string type (char[], char*) but an Arduino String in this case would make it easier to work with.

String myStr = "0b10000010000010000010000010000000";

void setup(){

    Serial.begin(115200);

    myStr.toUpperCase();
    myStr.replace("0B", "");
    uint32_t ul = strtoul(myStr.c_str(), NULL, 2);
    Serial.println(ul, BIN);

}

void loop(){

}